1. Cookies optimieren die Bereitstellung unserer Dienste. Mit der Nutzung unserer Dienste erklärst Du dich damit einverstanden, dass wir Cookies verwenden. Weitere Informationen
    Information ausblenden
  2. Willkommen im Forum von DIGITAL FERNSEHEN - dem führenden Portal für digitales Fernsehen, Medien und Entertainment. Wenn du hier neu bist, schau dich ruhig etwas um und melde dich an, um am Forengeschehen teilnehmen zu können.
    Information ausblenden

Zeitgesteuerter Senderwechsel im THC

Dieses Thema im Forum "Terratec" wurde erstellt von spem, 24. Dezember 2007.

  1. spem

    spem Neuling

    Registriert seit:
    24. Dezember 2007
    Beiträge:
    5
    Technisches Equipment:
    Cinergy Hybrid T USB XS
    Aktive Zimmerantenne TechniSat Digitenne-TT1
    Notebook BenQ Joybook R23 (1024 RAM, THC läuft mit 800MHz)
    Grafikkarte: VIA/S3G UniChrome Pro IGP (64 MB Shared Memory)
    Windows XP Home SP2
    Anzeige
    Ich wechsle gerne den Sender wenn Werbung kommt,
    vergesse aber oft wieder rechtzeitig zurück
    zu schalten.
    Daher habe ich mir ein kleines Programm für
    das kostenlose Automationsprogramm
    Autohotkey Version 1.0.47.05
    (www.autohotkey.com)
    (ca. 2 MB Downloadgröße)
    geschrieben, das automatisch den Sender wechselt.
    Ich gebe meinen Wunsch-Sender und die Wartezeit
    an und brauche mich um's zurückschalten nicht
    mehr zu kümmern.
    Falls etwas allgemeines Interesse besteht und
    die Forum-Moderatoren nichts dagegen haben,
    würde ich es gerne hier veröffentlichen.
    Das Programmlisting hat im Augenblick einen
    Umfang von ca. 350 Zeilen

    Gruß
    Günther
     
  2. spem

    spem Neuling

    Registriert seit:
    24. Dezember 2007
    Beiträge:
    5
    Technisches Equipment:
    Cinergy Hybrid T USB XS
    Aktive Zimmerantenne TechniSat Digitenne-TT1
    Notebook BenQ Joybook R23 (1024 RAM, THC läuft mit 800MHz)
    Grafikkarte: VIA/S3G UniChrome Pro IGP (64 MB Shared Memory)
    Windows XP Home SP2
    AW: Zeitgesteuerter Senderwechsel im THC

    ; Hallo liebe THC Benutzer,
    ; dies ist meine momentane Lösung um einen zeitgesteuerten
    ; Senderwechsel im THC zu bewerkstelligen. Es ist ein Skript
    ; das mit dem Programm Autohotkey Version 1.0.47.05,
    ; www.autohotkey.com, läuft. Autohotkey kann es auch in eine
    ; eigenständige EXE-Datei compilieren.
    ; Vielleicht ist es für den einen oder anderen brauchbar.
    ; Über Verbesserungsvorschläge und Bugreports würde ich
    ; mich freuen.
    ; Aus technischen Gründen muß ich das Skript in 2 Teile posten.
    ; Gruß
    ; Günther

    /*
    Zeitgesteuerter Senderwechsel im TerraTec Home Cinema

    Programm: ZS_THC.ahk
    Version : 0.2.0
    Datum : 27.12.2007

    Getestet mit:
    Autohotkey Version 1.0.47.05, www.autohotkey.com
    AutoHotkey ist eine freie Open-Source
    Skriptsprache für Windows, Skripte können in
    EXE-Dateien compiliert werden.
    TerraTec Home Cinema: 5.41.00.228
    Windows XP Home Edition Service Pack 2 (Build 2600)

    Die Timer-Funktionen "UpdateUhrzeit" und "UpdateCountdown"
    sind entstanden durch Inspiration von Button_Clock_WINXP.ahk
    geschrieben von A.N.Suresh Kumar aka "Goyyah".

    Beschreibung:
    Zeitgesteuerter Senderwechsel im "TerraTec Home Cinema".

    Mit dem Schalter "Gerade laufenden Sender wählen" kann
    der aktuelle im THC laufende Sender aus der Senderliste
    ausgewählt werden, ansonsten den Sender aus dem
    DropDown-Fenster auswählen.
    Der Schalter "Start" startet den Senderwechsel.
    Ist die Option "TV-Fenster On Top" angeklickt,
    bleibt nach dem Senderwechsel das TV-Fenster im
    Vordergrund, ansonsten wird wieder das Fenster in den
    Vordergrund geholt, das vor dem Senderwechsel aktiv war.
    Solange das Programm in der Warteschleife läuft,
    läßt sich der Senderwechsel mit 'Stop' abbrechen.

    Bei der Vielzahl der existierenden Systeme kann ich
    natürlich nicht garantieren, das das Timing des
    Programms auf jedem Rechner ohne Probleme läuft.
    Use it on your own risk.

    Benötigt wird:
    1 Text-Datei mit Namen "THC_ZS_Sender.txt".
    Die Datei muß eigenhändig angelegt werden
    und muß sich im gleichen Verzeichnis
    von ZS_THC.ahk bzw. ZS_THC.exe befinden.
    In dieser Datei stehen untereinander die Sendernamen
    mit ihrer Sendernummer aus dem "TerraTec Home Cinema",
    die als Auswahl zur Verfügung stehen sollen.
    Optional können noch Wartezeiten in Minuten für
    die einzelnen Sender mit angegeben werden.
    Das Semikolon dient als Kommentar- und Trennzeichen.

    Beispiel für den Inhalt von "THC_ZS_Sender.txt":
    ; THC_ZS_Sender.txt
    ; TerraTec Home Cinema-Senderliste für ZS_THC.ahk
    ; Bitte auf genaue Groß- und Kleinschreibung der
    ; Sendernamen achten!
    01. Das Erste
    02. ZDF
    12. Phoenix
    ; Der nächste Sender hat eine 8 als festgelegte
    ; Minuten-Wartezeit. Diese Zahl kann im Programm
    ; überschrieben werden und wiederbelebt werden
    ; indem man die Minutenzahl auf 0 stellt.
    14. ProSieben ; 8
    15. N24 ; 1:40 ; Mit Sekundenzahl

    Der Punkt hinter den Zahlen ist wichtig, da er als
    Trennzeichen vom Programm gebraucht wird um
    Sendernummer und Sendername zu trennen.

    Die wichtigsten Tastenkombinationen:
    Alt + s = Programmwechsel starten.
    Alt + t = Programmwechsel abbrechen.
    Alt + x = Programm beenden.
    */
    #NoEnv
    #SingleInstance force
    #WinActivateForce
    DetectHiddenWindows, On
    DetectHiddenText, On
    AutoTrim, On
    SetTitleMatchMode, 3
    SetWorkingDir, %A_ScriptDir%
    ; Process, Priority, , High
    THC = TerraTec Home Cinema
    THC2 = TERRATEC HOME CINEMA
    Menu, Tray, Add, &Beenden, GuiClose

    Loop ; Senderliste einlesen
    {
    FileReadLine, line, %A_WorkingDir%\ZS_THC_Sender.txt
    , %A_Index%
    If ErrorLevel
    Break
    StringLeft, ch, line, 1
    ; nur Zeilen die mit einer Zahl beginnen werden erfaßt
    If ch is number
    {
    ; Kommentarzeile entfernen
    StringSplit, word_array, line, `;
    line1 = %word_array1%
    ; Sender-Minutenwartezeit auslesen
    IfInString, line, `;
    {
    line2 = %word_array2%
    If line2 is not Number
    IfInString, line2,: ; Sekunden vorhanden
    line2 = %line2%
    else
    line2 = 0
    Else
    Transform, line2, Round, line2
    }
    Else
    line2 = 0

    DropDownListSender1 = %DropDownListSender1%%line1%|
    DropDownListZeit1 = %DropDownListZeit1%%line2%|
    }
    }

    ; Zeige den aktiven Sender in der DropDownliste an
    ; falls THC schon läuft.
    SNr := FindTVPosNum(DropDownListSender1, chr(124), chr(46))
    If SNr = 0
    SNr = 1

    StringLeft, Aktuelle_Zeit, A_now ,12
    Aktuelle_Zeit = %Aktuelle_Zeit%00

    ; Fenster-Farben
    Gui, Color , Black, Black

    Gui, Font, S18 CDefault, Verdana

    Gui, Add, Text,
    . x16 y10 w300 h40 cSilver
    , S&ender wählen:
    Gui, Add, DropDownList,
    . x26 y50 w325 R12 cRed Choose%SNr%
    . gDropDownListSender vDropDownListSender
    , %DropDownListSender1%

    Gui, Font, S11 CDefault, Verdana
    Gui, Add, Button,
    . x360 y48 w145 h40 cSilver
    . gButtonSender vButtonSender, &Gerade laufenden Sender wählen
    Gui, Font, S18 CDefault, Verdana


    Gui, Add, Checkbox,
    . x26 y95 w300 h40 cSilver Checked1
    . gCheckboxTVFensterOnTop vCheckboxTVFensterOnTop
    , TV-&Fenster On Top
    Gui, Add, Text,
    . x16 y150 w250 h40 cSilver
    , Wartezeit wählen:
    Gui, Add, Checkbox,
    . x26 y190 w140 h40 cSilver Checked0
    . gCheckboxMinuten vCheckboxMinuten
    , &Minuten:

    Gui, Add, Edit,
    . x170 y190 w70 h40 cRed vEditMinuten
    . gEditMinuten +Center Number Limit2, %EditMinuten%
    Gui, Add, UpDown, Range0-90

    Gui, Font, S13 CDefault, Verdana
    Gui, Add, Text,
    . x250 y190 w250 h20 cYellow vZeitAusSenderliste1,
    Gui, Add, Text,
    . x250 y210 w250 h20 cYellow vZeitAusSenderliste2,

    Gui, Font, S18 CDefault, Verdana
    Gui, Add, Checkbox,
    . x26 y250 w140 h40 cSilver Checked0
    . gCheckboxUhrzeit vCheckboxUhrzeit
    , &Uhrzeit :
    Gui, Add, DateTime,
    . x170 y250 w140 h40
    . Choose%Aktuelle_Zeit% gDateTimeMyTime vDateTimeMyTime, Time

    Gui, Add, Button,
    . x16 y330 w150 h40 cSilver
    . gButtonStart vButtonStart, &Start
    Gui, Add, Button,
    . x355 y330 w150 h40 cSilver
    . gButtonStop vButtonStop, S&top

    Gui, Font, S16 CDefault, Verdana
    Gui, Add, Text,
    . x16 y390 w500 h40 cSilver
    . vInfo, Info

    ; Button Stop deaktivieren
    GuiControl, Disable, ButtonStop

    ; Checkbox Minuten aktivieren
    Gosub CheckBoxMinuten

    GuiControl, Focus, ButtonStart ; Set keyboard Focus

    Gui, Show, AutoSize,Zeitgesteuerter Senderwechsel im %THC2%

    Return

    ; =========================
    ; Sub`s
    ; =========================
    ButtonSender:
    ; Zeige den aktiven Sender in der DropDownliste an
    ; falls THC schon läuft.
    SNr := FindTVPosNum(DropDownListSender1, chr(124), chr(46))
    If SNr = 0
    SNr = 1
    GuiControl, Choose, ComboBox1, %SNr%
    gosub SenderWahl
    return

    SenderWahl:
    Gui, Submit, NoHide ; alle Gui Variablen auslesen
    Sender = %DropDownListSender% ; gewählter Sender
    ; Sender-String am Punkt splitten
    StringSplit, word_array, Sender ,.
    SenderNr = %word_array1% ; Sendernummer extrahieren
    SenderName = %word_array2% ; Sendername extrahieren
    DropDownListMinuten = -1

    If SenderNr is not Number
    SenderNr = -1
    Else
    {
    ; Feste Minuten-Wartezeit
    ; des aktuellen Senders ermitteln
    Loop, Parse, DropDownListSender1,`|
    {
    ; Sender-String am Punkt splitten
    StringSplit, tmp, A_LoopField ,.
    If SenderNr = %tmp1%
    {
    index = %A_Index%
    Loop, Parse, DropDownListZeit1,`|
    {
    If index = %A_Index%
    {
    DropDownListMinuten = %A_LoopField%
    Break
    }
    }
    If DropDownListMinuten <> -1
    Break
    }
    }
    IfInString, DropDownListMinuten,:
    {
    StringSplit, tmp, DropDownListMinuten ,`:
    DropDownListMin = %tmp1%
    DropDownListSek = %tmp2%
    }
    }

    If (DropDownListMinuten <> 0) and (EditMinuten = 0)
    {
    if DropDownListSek > 0
    msg = %DropDownListMin%:%DropDownListSek%
    else
    msg = %DropDownListMinuten%
    GuiControl,, ZeitAusSenderliste1, Minutenzahl aus Senderliste
    GuiControl,, ZeitAusSenderliste2, wird benutzt: %msg%
    }
    Else
    {
    GuiControl,, ZeitAusSenderliste1,
    GuiControl,, ZeitAusSenderliste2,
    }
    Return

    DateTimeMyTime:
    GuiControl,, Info,
    Return

    DropDownListSender:
    Gosub SenderWahl
    If DropDownListMinuten > 0
    GuiControl,, EditMinuten,0
    GuiControl,, Info,
    Return

    CheckBoxTVFensterOnTop:
    GuiControl,, Info,
    Return

    CheckBoxMinuten:
    ; Saves the contents of each control to its associated variable
    Gui, Submit, NoHide
    If EditMinuten = 0
    Gosub SenderWahl
    GuiControl,, CheckboxUhrzeit,0
    GuiControl,, CheckboxMinuten,1
    GuiControl, Disable , DateTimeMyTime ; Uhrzeit
    GuiControl, Enable , EditMinuten ; Minuten
    Gui, Font, S12 cYellow , Verdana
    GuiControl, Font, ZeitAusSenderliste1
    GuiControl, Font, ZeitAusSenderliste2
    Return

    EditMinuten:
    ; Saves the contents of each control to its associated variable
    Gui, Submit, NoHide
    If EditMinuten > 90
    GuiControl,, EditMinuten, 90
    If EditMinuten = 0
    Gosub SenderWahl
    Else
    {
    DropDownListMinuten = -1
    GuiControl,, ZeitAusSenderliste1,
    GuiControl,, ZeitAusSenderliste2,
    }
    GuiControl,, Info,
    Return

    CheckBoxUhrzeit:
    ; Saves the contents of each control to its associated variable
    Gui, Submit, NoHide
    GuiControl,, CheckboxUhrzeit,1
    GuiControl,, CheckboxMinuten,0
    If EditMinuten = 0
    Gosub SenderWahl
    GuiControl, Enable , DateTimeMyTime ; Uhrzeit
    GuiControl, Disable , EditMinuten ; Minuten
    Gui, Font, S12 cSilver , Verdana
    GuiControl, Font, ZeitAusSenderliste1
    GuiControl, Font, ZeitAusSenderliste2
    Return
     
  3. spem

    spem Neuling

    Registriert seit:
    24. Dezember 2007
    Beiträge:
    5
    Technisches Equipment:
    Cinergy Hybrid T USB XS
    Aktive Zimmerantenne TechniSat Digitenne-TT1
    Notebook BenQ Joybook R23 (1024 RAM, THC läuft mit 800MHz)
    Grafikkarte: VIA/S3G UniChrome Pro IGP (64 MB Shared Memory)
    Windows XP Home SP2
    AW: Zeitgesteuerter Senderwechsel im THC

    /*
    Zeitgesteuerter Senderwechsel im TerraTec Home Cinema - 2. Teil
    Bitte dieses Programmteil zu dem ersten Teil hinzufügen.

    Programm: ZS_THC.ahk
    Version : 0.2.0
    Datum : 27.12.2007

    */

    UpdateUhrzeit:
    Gui, Submit, NoHide
    hh := SubStr(DateTimeMyTime, 9 , 2) ; Stunden
    mm := SubStr(DateTimeMyTime, 11 , 2) ; Minuten
    ss := SubStr(DateTimeMyTime, 13 , 2) ; Sekunden
    SenderwechselZeit = %hh%:%mm%:%ss%
    FormatTime, Aktuelle_Zeit, , HH:mm:ss
    msg = Senderwechsel: %SenderwechselZeit% Uhr
    GuiControl,, Info, %msg% / %Aktuelle_Zeit%
    If Aktuelle_Zeit = %SenderwechselZeit%
    {
    SetTimer, UpdateUhrzeit, off
    Gosub Senderwechsel
    }
    If not KeepRunning
    {
    SetTimer, UpdateUhrzeit, off
    Gosub ControlOn
    }
    Return

    Senderwechsel:
    If KeepRunning
    {
    Gosub SenderWahl
    Gui, Font, S16 cYellow , Verdana
    GuiControl, Font, Info
    GuiControl,, Info, Sender wird gewechselt...
    WinGetActiveTitle, Title ; aktuelles Fenster merken
    BlockInput, On ; Tastatur und Maus sperren
    WinWait, %THC%, 3
    IfWinNotActive, %THC%, , WinActivate, %THC%,
    WinWaitActive, %THC%, 3

    ;-------------------------------
    ; Sendernummer an THC abschicken
    ;-------------------------------
    StringLeft, n1, SenderNr, 1
    StringRight, n2, SenderNr, 1
    If n1 > 0
    ControlSend, Static1, {%n1%}, %THC%
    ControlSend, Static1, {%n2%}, %THC%
    ;-------------------------------

    ; Checkbox "Senderfenster On Top" auswerten
    GuiControlGet, CheckboxTVFensterOnTop,,CheckboxTVFensterOnTop
    If CheckboxTVFensterOnTop = 1
    fenster = %SenderName%
    Else
    fenster = %Title%

    IfWinNotActive, %fenster%, , WinActivate, %fenster%,
    WinWaitActive, %fenster%, , 3
    Gui, Font, S16 cTeal , Verdana
    GuiControl, Font, Info
    GuiControl,, Info, Aktueller Sender: %SenderName%
    BlockInput, Off ; Tastatur und Maus entsperren
    }
    Gosub ControlOn
    Return

    ButtonStart:
    Gosub ControlOff
    IfWinNotExist, %THC%
    {
    GuiControl,, Info, Fehler: %THC% nicht aktiv!
    Gosub ControlOn
    }
    Else
    {
    If SenderNr > -1
    {
    Gui, Font, S16 cRed, Verdana
    GuiControl, Font, Info
    ; alle GUI Variablen mit Wert belegen
    KeepRunning := true
    GuiControl, Focus, ButtonStop ; Set keyboard Focus

    If CheckboxUhrzeit = 1 ; Uhrzeit gewählt
    {
    SetTimer, UpdateUhrzeit, 1000
    Gosub UpdateUhrzeit
    }
    Else ; Minuten gewählt
    {
    Gosub SubmitTime
    Gosub UpdateCountdown
    }
    }
    Else
    {
    Gui, Font, S16 cSilver , Verdana
    GuiControl, Font, Info
    GuiControl,, Info, Fehler: Bitte Sender wählen!
    }
    }
    Return

    ButtonStop:
    Tooltip
    SetTimer, UpdateUhrzeit, off
    SetTimer, UpdateCountdown, off
    keepRunning := false
    Gosub ControlOn
    If CheckboxUhrzeit = 1
    Gosub CheckBoxUhrzeit
    Else
    Gosub CheckBoxMinuten
    GuiControl, Focus, ButtonStart ; Set keyboard Focus
    GuiControl,, Info, Senderwechsel wurde abgebrochen!
    Return

    ControlOff:
    GuiControl, Disable , DropDownListSender
    GuiControl, Disable , ButtonSender
    GuiControl, Disable , CheckboxTVFensterOnTop
    GuiControl, Disable , CheckboxUhrzeit
    GuiControl, Disable , CheckboxMinuten
    GuiControl, Disable , DateTimeMyTime ; Uhrzeit
    GuiControl, Disable , EditMinuten ; Minuten
    GuiControl, Disable , ButtonStart
    GuiControl, Enable , ButtonStop
    Return

    ControlOn:
    GuiControl, Enable , DropDownListSender
    GuiControl, Enable , ButtonSender
    GuiControl, Enable , CheckboxTVFensterOnTop
    GuiControl, Enable , CheckboxUhrzeit
    GuiControl, Enable , CheckboxMinuten
    GuiControl, Enable , DateTimeMyTime ; Uhrzeit
    GuiControl, Enable , EditMinuten ; Minuten
    GuiControl, Enable , ButtonStart
    GuiControl, Disable, ButtonStop
    GuiControlGet, CheckboxUhrzeit,,CheckboxUhrzeit
    If CheckboxUhrzeit = 1
    Gosub CheckBoxUhrzeit
    Else
    Gosub CheckBoxMinuten
    Return

    UpdateCountdown:
    ; Countdown-Update
    T = 20000101%CountDown%
    T += (C - A_TickCount)/1000,Seconds

    FormatTime FormdT, %T%, HH:mm:ss
    GuiControl,, Info, Zeit bis zum Senderwechsel: %FormdT%
    ; StringRight, Tm, T, 3
    ; If Tm < 100
    ; {
    ; StringRight, Ts, T, 2
    ; if Ts < 31
    ; ToolTip, Sender wird gewechselt in %Ts% Sekunden, 10,10
    ; }

    If KeepRunning=false
    FormdT = 00:00:00

    IfEqual FormdT, 00:00:00
    {
    SetTimer UpdateCountdown, Off
    ; Do not Timeout Messagebox if value
    ; is lower zero or not valid
    If DefinedTime > 0
    MsgBox, 4096,,It's time!
    Else
    {
    Gosub Senderwechsel
    Gosub ControlOn
    }
    }
    Return

    ; Set new time for Timer
    SubmitTime:
    Gui, Submit, NoHide
    If (DropDownListMinuten <> 0) and (EditMinuten = 0)
    If InStr(DropDownListMinuten,:)
    {
    StringSplit, tmp, DropDownListMinuten ,:
    Minutes = %tmp1%
    Seconds = %tmp2%
    }
    else
    {
    Minutes = %DropDownListMinuten%
    Seconds = 0
    }
    Else
    {
    Minutes = %EditMinuten%
    Seconds = 0
    GuiControl,, ZeitAusSenderliste1,
    GuiControl,, ZeitAusSenderliste2,
    }

    If Minutes > 59
    {
    Hours := Floor( Minutes / 60 )
    Minutes := Minutes - Hours * 60
    }
    Else
    {
    Hours = 0
    }

    If Hours < 10
    Hours := 0 . Hours
    If Minutes < 10
    Minutes := 0 . Minutes
    If Seconds < 10
    Seconds := 0 . Seconds
    SetTimer, UpdateCountdown, 500
    CountDown = %Hours%%Minutes%%Seconds% ; 6 Digits = HHmmSS
    DefinedTime = -1
    C = %A_TickCount%
    Return

    ; Suche die Positionsnummer des aktiven Senders
    ; in der Senderliste
    FindTVPosNum(liste, delim1, delim2)
    {
    local n, tmp, var
    n = 0
    Loop, Parse, liste, %delim1%
    {
    ; Listen-String am Punkt splitten
    StringSplit, tmp, A_LoopField , %delim2%
    var = %tmp2%
    IfWinExist, %var%
    {
    n = %A_Index%
    break
    }
    }
    Return, n
    }

    ; For Debugging purpose
    debug:
    ListVars
    Pause
    Return

    ; For Debugging purpose
    tt(var)
    {
    ToolTip, %var%
    Sleep, 500
    }

    !x:: ; Programm beenden mit Alt + x
    Gosub GuiClose
    Return

    GuiClose:
    ExitApp
    ; End of Code
     
  4. spem

    spem Neuling

    Registriert seit:
    24. Dezember 2007
    Beiträge:
    5
    Technisches Equipment:
    Cinergy Hybrid T USB XS
    Aktive Zimmerantenne TechniSat Digitenne-TT1
    Notebook BenQ Joybook R23 (1024 RAM, THC läuft mit 800MHz)
    Grafikkarte: VIA/S3G UniChrome Pro IGP (64 MB Shared Memory)
    Windows XP Home SP2
    AW: Zeitgesteuerter Senderwechsel im THC

    Ich habe gerade einen Hänger beim Testen erlebt und daher
    die Unterfunktion "Senderwechsel" nochmal überarbeitet:

    Senderwechsel:
    If KeepRunning
    {
    Gosub SenderWahl
    Gui, Font, S16 cYellow , Verdana
    GuiControl, Font, Info
    ; BlockInput, On ; Tastatur und Maus sperren
    GuiControl,, Info, Sender wird gewechselt...
    WinGetActiveTitle, Title ; aktuelles Fenster merken
    WinWait, %THC%, 5
    IfWinNotActive, %THC%, , WinActivate, %THC%,
    ;-------------------------------
    ; Sendernummer an THC abschicken
    ;-------------------------------
    loop, 3
    {
    WinWaitActive, %THC%, 5
    IfWinActive %THC%
    {
    StringLeft, n1, SenderNr, 1
    StringRight, n2, SenderNr, 1
    If n1 > 0
    ControlSend, Static1, {%n1%}, %THC%
    ControlSend, Static1, {%n2%}, %THC%
    break
    }
    else
    {
    BlockInput, Off ; Tastatur und Maus entsperren
    GuiControl,, Info, Sender wurde nicht gewechselt!
    }
    }
    ;-------------------------------

    ; Checkbox "Senderfenster On Top" auswerten
    GuiControlGet, CheckboxTVFensterOnTop,,CheckboxTVFensterOnTop
    If CheckboxTVFensterOnTop = 1
    fenster = %SenderName%
    Else
    fenster = %Title%

    IfWinNotActive, %fenster%, , WinActivate, %fenster%,
    WinWaitActive, %fenster%, , 3
    Gui, Font, S16 cTeal , Verdana
    GuiControl, Font, Info
    BlockInput, Off ; Tastatur und Maus entsperren
    GuiControl,, Info, Aktueller Sender: %SenderName%
    }
    Gosub ControlOn
    Return
     
  5. spem

    spem Neuling

    Registriert seit:
    24. Dezember 2007
    Beiträge:
    5
    Technisches Equipment:
    Cinergy Hybrid T USB XS
    Aktive Zimmerantenne TechniSat Digitenne-TT1
    Notebook BenQ Joybook R23 (1024 RAM, THC läuft mit 800MHz)
    Grafikkarte: VIA/S3G UniChrome Pro IGP (64 MB Shared Memory)
    Windows XP Home SP2
    AW: Zeitgesteuerter Senderwechsel im THC

    Ich sah gerade einen Smiley im Code, er muß einen Doppelpunkt :
    mit schließender Klammer ) ersetzt werden.
     

Diese Seite empfehlen